LaTeX Forum

Ich glaube, das wäre in den sonstigen Tools besser aufgehoben.

@echo off
set ORDNERNAME="01 - LaTex"
set DATEINAME=Backup_LaTex
set BACKUPZIEL="00 - Backup"

echo Kommetar eingeben (ohne Sonderzeichen und Umlaute):
set /p KOMMENTAR=
echo.
echo Backup laeuft....
echo.

set DATUM=%date:~6,4%.%date:~3,2%.%date:~0,2%
set ZEIT=%time:~0,2%.%time:~3,2%.%time:~6,2%
if "%ZEIT:~0,1%"==" " set ZEIT=0%ZEIT:~1,8%

REM Cleanup ausfuehren
cd %ORDNERNAME% 1>nul
IF ERRORLEVEL 1 goto endOrdnerFehlt
call cleanup.bat
cd .. 1>nul

REM Sicherung Latex und verschieben
C:\PROGRA~1\7-Zip\7z.exe a -t7z -mx9 %DATEINAME%_%DATUM%_%ZEIT%.7z %ORDNERNAME%\ -xr!*.pdf -xr!cleanup*.bat -xr!Abbildungen 1>nul
IF ERRORLEVEL 1 goto endFehler7z
move %DATEINAME%_%DATUM%_%ZEIT%.7z %BACKUPZIEL%\%DATEINAME%_%DATUM%_%ZEIT%.7z 1>nul
IF ERRORLEVEL 1 goto endVerschiebenFehler

REM Sicherung Abbildungsordner und verschieben
C:\PROGRA~1\7-Zip\7z.exe a -t7z -mx9 Abbildungen.7z %ORDNERNAME%\Abbildungen >nul
IF ERRORLEVEL 1 goto endFehler7z
del %BACKUPZIEL%\Abbildungen.7z 1>nul
move Abbildungen.7z %BACKUPZIEL%\Abbildungen.7z 1>nul
IF ERRORLEVEL 1 goto endVerschiebenFehler

REM Kommentar Speichern
cd %BACKUPZIEL% 1>nul
echo %DATUM:.=:% %ZEIT:.=:% %KOMMENTAR%>>%DATEINAME%".txt"


:endIO
echo Backup fehlerfrei erstellt
goto endEnd

:endFehler7z
echo Fehler beim Packen der Dateien
goto endEnd


:endOrdnerFehlt
echo Ordner %ORDNERNAME% wurde nicht gefunden
goto endEnd

:endVerschiebenFehler
echo Daten konnten nicht in %BACKUPZIEL% verschoben werden
goto endEnd

:endEnd
PAUSE

del *.alof 2>nul
del *.alot 2>nul
del *.aloc 2>nul
del *.aux 2>nul
del *.bcf 2>nul
del *.log 2>nul
del *.xml 2>nul
del *.gz 2>nul
del *.toc 2>nul
del *.atoc 2>nul
del *.lof 2>nul
del *.lot 2>nul
del *.bbl 2>nul
del *.blg 2>nul
del *.dvi 2>nul
del *.out.ps 2>nul
del *.out 2>nul
del *busy* 2>nul
del *-figure*.* 2>nul

Hallo Zusammen.
für jeden der Permanent an einer Wissenschaftlichen arbeit arbeitet:

Habe mal ein Batch-Backupskript geschrieben. Es läuft mit 7zip (muss im standartverzeichniss installiert sein. Gesichert wird der Ordnerinhalt vom LaTexordner ohne PDF-Dateien. Zuvor wird die Datei cleanup.bat ausgeführt damit das Verzeichnis bereinigt ist. Der Unterordner Abbildungen wird getrennt gesichert (die alte Sicherung der Abbildung wird gelöscht; wegen Speicherplatz). Die Tex-Dateien werden mit Dateiname: JJJJ.MM.TT HH.MM.SS gesichert und in ein Backup-Ordner verschoben. Außerdem wird eine Txt datei angelegt wo ein Änderungskommtar aus der Batch mit Datum und Uhrzeit hinterlegt wird. Kleine Versionsverwaltung also

Viele Grüße aus dem Westerwald

PS: Warum wird Bonn bei der Hauptstadt-Frage akzeptiert? :D
Backup.bat (im Übergeordneten Ordner)
[code]
@echo off
set ORDNERNAME="01 - LaTex"
set DATEINAME=Backup_LaTex
set BACKUPZIEL="00 - Backup"

echo Kommetar eingeben (ohne Sonderzeichen und Umlaute):
set /p KOMMENTAR=
echo.
echo Backup laeuft....
echo.

set DATUM=%date:~6,4%.%date:~3,2%.%date:~0,2%
set ZEIT=%time:~0,2%.%time:~3,2%.%time:~6,2%
if "%ZEIT:~0,1%"==" " set ZEIT=0%ZEIT:~1,8%

REM Cleanup ausfuehren
cd %ORDNERNAME% 1>nul
IF ERRORLEVEL 1 goto endOrdnerFehlt
call cleanup.bat
cd .. 1>nul

REM Sicherung Latex und verschieben
C:\PROGRA~1\7-Zip\7z.exe a -t7z -mx9 %DATEINAME%_%DATUM%_%ZEIT%.7z %ORDNERNAME%\ -xr!*.pdf -xr!cleanup*.bat -xr!Abbildungen 1>nul
IF ERRORLEVEL 1 goto endFehler7z
move %DATEINAME%_%DATUM%_%ZEIT%.7z %BACKUPZIEL%\%DATEINAME%_%DATUM%_%ZEIT%.7z 1>nul
IF ERRORLEVEL 1 goto endVerschiebenFehler

REM Sicherung Abbildungsordner und verschieben
C:\PROGRA~1\7-Zip\7z.exe a -t7z -mx9 Abbildungen.7z %ORDNERNAME%\Abbildungen >nul
IF ERRORLEVEL 1 goto endFehler7z
del %BACKUPZIEL%\Abbildungen.7z 1>nul
move Abbildungen.7z %BACKUPZIEL%\Abbildungen.7z 1>nul
IF ERRORLEVEL 1 goto endVerschiebenFehler

REM Kommentar Speichern
cd %BACKUPZIEL% 1>nul
echo %DATUM:.=:% %ZEIT:.=:% %KOMMENTAR%>>%DATEINAME%".txt"


:endIO
echo Backup fehlerfrei erstellt
goto endEnd

:endFehler7z
echo Fehler beim Packen der Dateien
goto endEnd


:endOrdnerFehlt
echo Ordner %ORDNERNAME% wurde nicht gefunden
goto endEnd

:endVerschiebenFehler
echo Daten konnten nicht in %BACKUPZIEL% verschoben werden
goto endEnd

:endEnd
PAUSE
[/code]

cleanup.bat:
[code]
del *.alof 2>nul
del *.alot 2>nul
del *.aloc 2>nul
del *.aux 2>nul
del *.bcf 2>nul
del *.log 2>nul
del *.xml 2>nul
del *.gz 2>nul
del *.toc 2>nul
del *.atoc 2>nul
del *.lof 2>nul
del *.lot 2>nul
del *.bbl 2>nul
del *.blg 2>nul
del *.dvi 2>nul
del *.out.ps 2>nul
del *.out 2>nul
del *busy* 2>nul
del *-figure*.* 2>nul
[/code]